4D Internet Commands v12.1

SMTP_Send

ホーム

 
4D Internet Commands v12.1
SMTP_Send

 

SMTP_Send 


 

SMTP_Send ( smtp_ID {; sessionParam} ) -> 戻り値 
引数   説明
smtp_ID  倍長整数 in メッセージ参照
sessionParam  倍長整数 in 1 = SSLを使用, 0または省略 = SSLを使用しない
戻り値  整数 in エラーコード

説明   

SMTP_Send コマンドは smtp_ID で参照されるメッセージを送信します。しかしメモリからデータをクリアすることはありません。

smtp_IDSMTP_New コマンドで作成された倍長整数のメッセージ参照です。

オプションのsessionParam引数を使用すると、接続にSSLプロトコルを使用することができます:

  • 1を渡すと、SMTPサーバーへの接続はSSLで行われます (同期モード)、
  • 0を渡すかこの引数を省略すると、接続は標準の非保護モードで行われます。

例題  

この例題では、メッセージが作成され、スタティックな要素がループの外側で定義されています。そののち、[People] テーブルのレコード毎にメッセージがカスタマイズされ、送信されます。

 $error:=SMTP_New($smtp_id)
 $error:=SMTP_Host($smtp_id;"wkrp.com")
 $error:=SMTP_From($smtp_id;"herb_tarlick@wkrp.com")
 $error:=SMTP_ReplyTo($smtp_id;"bigguy@wkrp.com")
 $error:=SMTP_Subject($smtp_id;"Discounts on Ad Space!")
 FIRST RECORD([People])
 For($i;1;Records in selection([People]))
    If([People]Sales2Date>100000)
       $Body:=<>BigDiscText
    Else
       $Body:=<>SmlDiscText
    End if
    $Body:=Replace string($BoilerPlate;"<Salutation>";[People]Firstname)
    $error:=SMTP_To($smtp_id;[People]Email;1) `"To" ヘッダを新しい値で置き換える
    $error:=SMTP_Body($smtp_id;$Body)
    $error:=SMTP_Send($smtp_id)
    NEXT RECORD([People])
 End for
 $error:=SMTP_Clear($smtp_id)

 
プロパティ 

プロダクト: 4D Internet Commands
テーマ: IC メール送信
番号: 88989

 
履歴 

New
初出: 4D Internet Commands 6.5
変更: 4D Internet Commands v12.1

 
参照 

SMTP_New